接触单片机有几年的时间了，一直专注于如何在单片机上写一些应用，对单片机如何启动的知之甚少，惭愧惭愧。。。今天得空整理了一下，加深了对单片机的认识，如为什么定义data区里的变量重新开机的初始值为0。

单片机在开机上电后，会执行startup.A51文件的指令，我分析了一下某个项目中这个文件里的指令，在这里单片机会做如下几件事情：

1. 初始化8051硬件堆栈的大小和堆栈指针；
2. 初始化中断向量表，分配每个中断的入口地址和中断服务函数；
3. 初始化内部RAM空间，即DATA/IDATA，将内容清零；
4. 初始化外部RAM空间，即XDATA/PDATA，将内容清零；
5. 初始化SMALL/COMPACT/LARGE模式下reentrant函数使用的堆栈指针；
6. 调用main()函数，去执行我们编写的代码。

当用keil作为开发环境，创建一个工程时，需要选择所使用的单片机型号，然后Keil会将相应单片机的startup.A51文件拷贝到工程目录下，在编译时，该文件会被编译到最终的目标文件中。一般情况下，这个文件是不需要我们做修改的，保持默认状态即可，所以可能很多人对此文件不太熟悉。下面是具体的code以及我的个人分析：

$NOMOD51   ;取消8051对SFR的预定义，由用户自行定义。

; 以下定义3个SFR
sfr CLKSEL  = 0x8F
sfr P3 = 0xB0
sfr MMU_SEL = 0xC3

; 以下初始化IDATA, XDATA和PDATA存储区
IDATASTART  EQU 00H     ; the absolute start-address of IDATA memory
IDATALEN    EQU 100H        ; the length of IDATA memory in bytes.
;
XDATASTART  EQU 0H  ; the absolute start-address of XDATA memory
XDATALEN    EQU 0F00H   ; the length of XDATA memory in bytes.
;
PDATASTART  EQU 0H  ; the absolute start-address of PDATA memory
PDATALEN    EQU 100H    ; the length of PDATA memory in bytes.

; 定义存储PLL值的地址。
PLLADDR     EQU 0xEFFF
;

;  当函数是可重入的（用reentrant关键字修饰），以下初始化可重入函数所使用的堆栈， 考虑到了三种编译模式SMALL/COMPACT/LARGE。
;  Stack Space for reentrant functions in the SMALL model.
IBPSTACK    EQU 0   ; set to 1 if small reentrant is used.
IBPSTACKTOP EQU 0FFH+1  ; set top of stack to highest location+1.
;
;  Stack Space for reentrant functions in the LARGE model.  
XBPSTACK    EQU 0   ; set to 1 if large reentrant is used.
XBPSTACKTOP EQU 0FFFFH+1; set top of stack to highest location+1.
;
;  Stack Space for reentrant functions in the COMPACT model.    
PBPSTACK    EQU 0   ; set to 1 if compact reentrant is used.
PBPSTACKTOP EQU 0FFFFH+1; set top of stack to highest location+1.
;
;------------------------------------------------------------------------------
;   初始化PDATA区
;  Page Definition for Using the Compact Model with 64 KByte xdata RAM
;
;  The following EQU statements define the xdata page used for pdata
;  variables. The EQU PPAGE must conform with the PPAGE control used
;  in the linker invocation.
;
PPAGEENABLE EQU 1   ; set to 1 if pdata object are used.
PPAGE       EQU 0   ; define PPAGE number.
PPAGE_SFR       DATA    0A0H
START_GPNVM_CODE EQU    00H ; Start of Code
;
;------------------------------------------------------------------------------

; Standard SFR Symbols 
ACC     DATA    0E0H
B       DATA    0F0H
SP      DATA    81H
DPL     DATA    82H
DPH     DATA    83H
P2      DATA    0A0H

    NAME    ?C_STARTUP  ;定义这段汇编代码在obj文件中的名字
; 声明三个在外部定义的中断函数, 以便在本模块中调用
EXTRN CODE (TrqIsr)
EXTRN CODE (uartISR)
EXTRN CODE (FlashInterrupt)

; 声明段C_C51STARTUP和STACK存储位置
?C_C51STARTUP   SEGMENT   CODE
?STACK      SEGMENT   IDATA

; 选择STACK段，并设定STACK的size
        RSEG    ?STACK
        DS  96

; 选择地址0x00(CODE区)，并跳转到0x0200(CODE区)的位置      
        CSEG    AT  0x00
        LJMP    0x0200

        EXTRN CODE (?C_START)   ;声明外部段名 C_START，以便在本模块中调用
        PUBLIC  ?C_STARTUP      ;声明在本文件中定义的段C_STARTUP为public的，以供其他模块调用

; 选择地址0x0200(CODE区)，并跳转到 STARTUP1(CODE区)的位置
        CSEG    AT  0x0200      
?C_STARTUP: LJMP    STARTUP1

; 以下是中断向量表，分配每个中断的地址和对应的中断服务函数。
        CSEG AT START_GPNVM_CODE+0BH        ; IT timer 0
;       gpnvmVectorEtuCnt:
        LJMP TrqIsr
        RETI                    
;       LJMP    InterruptRoutineVectorEtuCnt

        CSEG AT START_GPNVM_CODE+13H        ; MMU COB or DOB or OVD
;       gpnvmVectorFault:
        LJMP uartISR            
        RETI

        CSEG AT START_GPNVM_CODE+23H        ; MMU COB or DOB or OVD
;       gpnvmVectorFault:
        LJMP FlashInterrupt         
        RETI

; 选择C_C51STARTUP段所在地址       
        RSEG    ?C_C51STARTUP
STARTUP1:
        MOV MMU_SEL,#01H    ; 初始化SFR: MMU_SEL
        MOV P3,#05H         ; 初始化SFR: P3

;初始化单片机的时钟频率
        MOV DPTR,#PLLADDR
        MOVX A,@DPTR
        ANL A, #0C0H
        MOV CLKSEL, A

; 初始化 IRAM (0x00 - 0xFF)
IF IDATALEN <> 0
        MOV R0,#IDATALEN - 1
;        MOV R1,#IDATASTART
        CLR A
IDATALOOP:  MOV @R0,A
;        INC R1
        DJNZ    R0,IDATALOOP
ENDIF
; 初始化 XRAM
IF XDATALEN <> 0
        MOV DPTR,#XDATASTART
        MOV R7,#LOW (XDATALEN)
  IF (LOW (XDATALEN)) <> 0
        MOV R6,#(HIGH (XDATALEN)) +1
  ELSE
        MOV R6,#HIGH (XDATALEN)
  ENDIF
        CLR A
XDATALOOP:  MOVX    @DPTR,A
        INC DPTR
        DJNZ    R7,XDATALOOP
        DJNZ    R6,XDATALOOP
ENDIF

; 初始化PDATA
IF PPAGEENABLE <> 0
        MOV P2,#PPAGE
ENDIF

IF PDATALEN <> 0
        MOV R0,#PDATASTART
        MOV R7,#LOW (PDATALEN)
        CLR A
PDATALOOP:  MOVX    @R0,A
        INC R0
        DJNZ    R7,PDATALOOP
ENDIF

; 初始化reentrant函数使用的堆栈指针(SMALL/COMPACT/LARGE)
IF IBPSTACK <> 0
EXTRN DATA (?C_IBP)

        MOV ?C_IBP,#LOW IBPSTACKTOP
ENDIF

IF XBPSTACK <> 0
EXTRN DATA (?C_XBP)

        MOV ?C_XBP,#HIGH XBPSTACKTOP
        MOV ?C_XBP+1,#LOW XBPSTACKTOP
ENDIF

IF PBPSTACK <> 0
EXTRN DATA (?C_PBP)
        MOV ?C_PBP,#LOW PBPSTACKTOP
ENDIF

        MOV SP,#?STACK-1        ;初始化堆栈指针，指向栈底

; 声明外部定义的函数B_SWITCH0，并调用之
EXTRN CODE (?B_SWITCH0)
        CALL    ?B_SWITCH0      ; init bank mechanism to code bank 0

        LJMP    ?C_START    ;调用main()函数

END

这个是编译输出文件.lst中的部分代码在code区的分配情况，结合汇编代码，我们可以知道在code区某个位置存放的是什么指令。

000000H   000002H   000003H   ---    OFFS..   CODE           ?CO?STTF06?3       ;此处存放的代码为 LJMP  0x0200
000003H   00000AH   000008H   ---    ---      **GAP**
00000BH   00000EH   000004H   ---    OFFS..   CODE           ?CO?STTF06?5       ;此处存放的代码为 LJMP TrqIsr
00000FH   000012H   000004H   ---    ---      **GAP**
000013H   000016H   000004H   ---    OFFS..   CODE           ?CO?STTF06?6       ;此处存放的代码为 LJMP uartISR
000017H   000022H   00000CH   ---    ---      **GAP**
000023H   000026H   000004H   ---    OFFS..   CODE           ?CO?STTF06?7       ;此处存放的代码为 LJMP FlashInterrupt
000027H   0001FFH   0001D9H   ---    ---      **GAP**
000200H   000202H   000003H   ---    OFFS..   CODE           ?CO?STTF06?4       ;此处存放的代码为 LJMP  STARTUP1
000203H   0006E9H   0004E7H   BYTE   UNIT     CODE           ?C?LIB_CODE
0006EAH   0007A0H   0000B7H   BYTE   UNIT     CODE           ?C_C51STARTUP      ;此处存放的代码为 段?C_C51STARTUP的内容，对单片机的硬件做初始化

下面是描述startup.A51的流程图，作为这次学习的总结。